Commodore 64 Basic - creating BIG characters
This time I got inspired by a chapter in the Commodore 64 programmers reference guide.
At first I just started to see If I could use the information on how the characters definitions are stored in memory and how you could read that information. Each definition of a screen character is stored in memory using the 8 bits per character line.
So for example the character A is defined as follows
0001100
0011110
0110011
0111111
0110011
0110011
0110011
The program reads the bytes from memory and transforms the bits into a string that is printed on the screen.
Note in the below code you need to replace the "[" charters into the character smaller then. (see line 260 next c : if len(mg$)[5 then print) as YouTube does not allow that character in the comment.
100 printchr$(147):dim cr(5)
110 poke56334,peek(56334)and254:poke 1,peek(1)and251
120 mg$=" just":gosub 200:mg$="for":gosub 200:mg$=" the":gosub 200
121 mg$="fun":gosub 200:mg$="of it":gosub 200
130 poke 1,peek(1)or4:poke56334,peek(56334)or1
140 goto 110
200 fori=1tolen(mg$):cr(i)=asc(mid$(mg$,i,1))and191:nexti
210 for r = 0 to 7
220 for c = 1 to len(mg$)
230 a=peek(53248+cr(c)*8+r)
240 for n=7 to 0 step-1:b(n)=int(a/2^n):a=a-(b(n)*2^n):next n
250 fort=0 to 7:print mid$(" "+chr$(113),1+b(7-t),1);:next t
260 next c : if len(mg$)[5 then print
270 next r : return
The program I started to experiment with this is the following small commodore Basic program.
120 printchr$(147):input "screen code set (1 or 2)"; cs
130 input "character number";ch: ch=ch*8
140 input "reverse y/n";r$ :if r$="y" then ch=ch+128*8:print
150 poke56334,peek(56334)and254:rem turns keyscan interrupts off
160 poke 1,peek(1)and251:rem switch out i/o and character rom in
170 uc=53248:if cs=2 then uc=55296
180 for i=0 to 7:a=peek(uc+ch+i)
190 for n=7to0 step-1:b(n)=int(a/2^n):a=a-(b(n)*2^n):next n
200 for t=0to7:print mid$(" "+chr$(113),1+b(7-t),1);:next t:print
210 next i
220 poke 1,peek(1) or 4: rem switch i/o back to normal operation
230 poke 56334,peek(56334)or1 :rem turns keyscan interrupts on
http://www.justforthefunofit.nl
On this page of the site you can watch the video online Commodore 64 Basic - creating BIG characters with a duration of hours minute second in good quality, which was uploaded by the user Just for the Fun of It – Commodore Retro & BASIC 09 February 2022, share the link with friends and acquaintances, this video has already been watched 1,976 times on youtube and it was liked by 51 viewers. Enjoy your viewing!
